Constructing Fractals and Fractal measures

This package focuses on self-similar fractals, which can be described by a finite set of self-similar maps. These maps are called similarities.

Similarities

Each similarity is of the form:

\[s_m(x)=\rho_mA_mx + \delta_m,\quad x\in\mathbb{R}^N,\]

where $\rho_m\in(0,1)$ is the contraction factor, $A_m\in\R^{N\times N}$ is a rotation matrix, and $\delta\in\R^{N}$ is a translation vector. Here we call $N\in\mathbb{N}$ the ambient dimension.

Similarity{N, T} <: AbstractSimilarity{N, T}

s₁ = Similarity(1/3, [0,0])
s₂ = Similarity(Float32(1/3), rand(3), [-1 0; 0 1])

s₂₁ = s₁ ∘ s₂
s₂⁻¹ = inv(s₂)
s₁³ = s₁^3

x = rand(2)
y = s₁(x)

Attractors

An iterated function system (IFS) is a set of $M$ similarities $\{s_m\}_{m=1}^M$, and an attractor of an iterated function system $\Gamma$ satisfies

\[\Gamma = \bigcup_{m=1}^M s_m(\Gamma)\]

Attractor{N, M, T} <: AbstractAttractor{N, M, T}

s₁ = Similarity(1/3, 0)
s₂ = Similarity(1/3, 2/3)
cantor_set = Attractor(s₁, s₂)

courage = Similarity(1/2, [0, 0])
wisdom  = Similarity(1/2, [1/2, 0])
power   = Similarity(1/2, [1/4, sqrt(3)/4])
sierpinski_triangle = Attractor(courage, wisdom, power, connectedness = Bool(ones(3,3)))

Fractal
├── AbstractAttractor
│   ├── Attractor
    ├── OneDimensionalAttractor
├── AbstractHomogenousAttractor
    ├── HomogenousAttractor
│   ├── OneDimensionalHomogenousAttractor

In general, an IFS attractor has a non-integer Hausdorff dimension. The Hausdorff dimension $d$ satisfies

\[\sum_{m=1}^M\rho_m^d = 1.\]

The following example constructs a Cantor set and displays its dimension.

s₁ = Similarity(1/3,0)
s₂ = Similarity(1/3,2/3)
Γ = Attractor(s₁, s₂)
print(Γ)

0.63-dimensional FractalIntegrals.OneDimensionalHomogenousAttractor{2, Float64}:
x ↦ 0.33x + 0.0
x ↦ 0.33x + 0.67

println("Full Hausdorff dimension of Cantor Set:", Γ.d)

Full Hausdorff dimension of Cantor Set:0.6309297535714574

Plotting attractors

Plots.plot has a method for a Attractor type.

plot(Γ, aspect_ratio=1)

Presets

You can create your own attractor from scratch, as explained above. But a range of preset attractors are available.

getfractal(T::Type, fractalname::Symbol; vargs...)
getfractal(T::Type, fractalname::String; vargs...)
getfractal(fractalname; vargs...)

Γ = getfractal("cantor set"; ρ = 1/4)

Γ = getfractal("sierpinskitriangle")
plot(Γ, aspect_ratio=1)

Sub-components

It is often convenient to talk about a subcomponent of a fractal $\Gamma$ which is a scaled copy of the original $\Gamma$. This is particularly useful when meshing the fractal with fractal mesh elements. To do this, vector indexing is used, for example for $\mathbf{m}=[m_1,\ldots,m_\ell]$,

\[\Gamma_{\mathbf{m}} = s_{m_1}\circ \ldots \circ s_{m_\ell} (\Gamma)\]

This can be achieved by treating attractors as vectors.

Γ₁ = Γ[1]
𝐦 = [3,2,3,1]
Γ₃₂₃₁ = Γ[𝐦]
plot!(Γ₁,markersize=1, aspect_ratio=1)
plot!(Γ₃₂₃₁,markersize=1.5, aspect_ratio=1)

Measures

We now consider a measure $\mu$ supported on a fractal attractor $\Gamma$. This is necessary to define integrals and integral equations on $\Gamma$. For an attractor defined with $M$ similarities, an invariant measure $\mu$ is defined by an associated set of probabilities $p_1,\ldots,p_M$ satisfying $\sum_{m=1}^M p_m =1$, such that

\[\mu(\Gamma_\mathbf{m}) = \left(\prod_{i=1}^\ell p_{m_i}\right)\mu(\Gamma).\]

InvariantMeasure{N, M, T, A <: AbstractAttractor{N, M, T}}

The Hausdorff Measure $\mathcal{H}^d$ is a special case of an Invariant Measure, where $p_m=\rho_m^d$ for $m=1,\ldots,M$. This ensures that the mass of the measure is, in some sense, spread evenly across $\Gamma$. A useful consequence is that if $\Gamma$ is invariant under any non-trivial rotations/reflections, then this is inherited by the Hausdorff measure.

HausdorffMeasure{N, M, T, A <: AbstractAttractor{N, M, T}}

The Hausdorff measure is the most natural measure for any fractal, and is used by default throughout FractalIntegrals. Recall that from an above example, $\Gamma$ represents the Sierpinski triangle.

# no weights specified
𝓗ᵈ = InvariantMeasure(Γ)
print(typeof(𝓗ᵈ))

HausdorffMeasure{2, 3, Float64, FractalIntegrals.HomogenousAttractor{2, 3, Float64}}

Sub-measures

A sub-measure is analogous to the definition of sub-attractor, and can be easily constructed using vector indices.

For some measure $\mu:\Gamma\to [0,\infty)$, it is the restriction $\mu_{\mathbf{m}}:=\mu|_{\Gamma_{\mathbf{m}}}$. It is mentioned in the above section that the field suppmeasure is difficult to estimate, but here it is computed automatically from $\mu$, via the identity

\[\mu_\mathbf{m}(\Gamma_{\mathbf{m}}) = \mu(s_{\mathbf{m}}(\Gamma)).\]

Plotting measures

When plot is used on an InvariantMeasure, colouring is used to represent the distribution of mass.

# create random set of probabilites
𝐩 = rand(3)
𝐩 = 𝐩/sum(𝐩)
μ = InvariantMeasure(Γ, 𝐩)
plot(μ, markersize = 1)

Measure
├── AbstractInvariantMeasure
│   ├── InvariantMeasure
│   ├── HausdorffMeasure
├── MeasureUnion